%let name=docbar;
filename odsout '.';

data mydata;
input year physicians physicians_per_person;
datalines;
1985 5933 222
1986 6160 231
1987 6497 242
1988 6491 237
1989 6729 241
1990 6941 244
1991 7108 243
1992 7299 244
1993 7508 246
1994 7607 244
1995 7884 249
1996 8153 252
1997 8405 256
1998 8617 260
1999 8990 265
2000 9173 266
2001 9584 .
;
run;

data mydata; set mydata;
format physicians comma6.0;
label physicians='Active Licensed Physicians';
label physicians_per_person='Physicians per 100,000 Population';
length my_html $200;
my_html=
 'title='||quote(
  'Year: '||trim(left(year))||'0d'x||
  'Physicians: '||trim(left(put(physicians,comma6.0)))||'0d'x||
  'per person: '||trim(left(physicians_per_person)))||
 ' href="docbar_info.htm"';
run;

goptions device=png;
goptions noborder;
 
ODS LISTING CLOSE;
ODS HTML path=odsout body="&name..htm" 
 (title="SAS/Graph bar & line plot - Licensed Physicians") style=sasweb;

/* for the bars */
pattern v=s c=gray55;
 
/* for the line */
symbol ci=black w=1 v=dot cv=black h=1.5;

goptions gunit=pct htitle=3 htext=2 ftitle="arial" ftext="arial";

axis1 c=olive order=(0 to 12000 by 2000) minor=none 
 label=(c=black angle=90 h=.15in) value=(c=black) offset=(0,0);

axis2 c=olive order=(0 to 300 by 50) minor=none 
 label=(c=black angle=90 h=.15in) value=(c=black) offset=(0,0);

axis3 label=none value=('1985' '' '1987' '' '1989' '' '1991' '' '1993' '' '1995' ''
  '1997' '' '1999' '' '2001') offset=(4,4);

title1 ls=1.5 "Active Licensed Physicians and Physicians";
title2 h=3 "per 100,000 Population, Oregon 1985-2001";

footnote "Sources: Oregon Board of Medical Examiners; Bureau of the Census - est.";

proc gbarline data=mydata;
bar year / type=sum sumvar=physicians 
 discrete outside=sum
 raxis=axis1 maxis=axis3 
 html=my_html
 des='' name="&name";
plot / type=sum sumvar=physicians_per_person
 axis=axis2
 html=my_html;
run;

quit;
ODS HTML CLOSE;
ODS LISTING;