%let name=ontime;
filename odsout '.';

/* 
Imitation of http://www.interconnect-wiring.com/images/cust_chart1.gif 

Note: This example uses fabricated data!
*/

goptions reset=global;

data mydata;
input date date9. items ontime;
format date monyy.;
format ontime percent6.0;
datalines;
15feb2005 553 1.0000
15mar2005 507 1.0000
15apr2005 586 1.0000
15may2005 488 1.0000
15jun2005 404 1.0000
15jul2005 306 1.0000
15aug2005 323 0.9905
15sep2005 531 0.9959
15oct2005 677 0.9600
15nov2005 695 0.9624
15dec2005 867 0.9229
15jan2006 557 0.9888
;
run;

data mydata; set mydata;
length htmlvar $1024;
htmlvar= 
 'title='||quote( 
  'Date: '|| trim(left(put(date,monyy.)))||'0D'x||
  'Deliveries: '|| trim(left(items))||'0D'x||
  'Ontime: '|| trim(left(put(ontime,percent8.2))))|| 
 ' href="ontime_info.htm"';
run;

data anno_img;
length  function $8;
xsys='3'; ysys='3'; hsys='3'; when='a';
function='move'; x=0; y=90; output;
function='image'; x=x+16; y=y+10; imgpath='fedex_logo.jpg'; style='fit'; output;
run;


goptions device=png;
goptions border;
 
ODS LISTING CLOSE;
ODS HTML path=odsout body="&name..htm" 
 (title="FedEx Ontime Deliveries (proof-of-concept)") style=htmlblue;

goptions gunit=pct htitle=4.5 htext=2.7 ftitle="albany amt/bold" ftext="albany amt/bold";

title1 ls=1.5 color=gray55 link='http://www.fedex.com' 
 "On-Time Delivery";

title2 " ";

footnote ls=1.2 j=l c=gray move=(+3,+0) 
 "Note: This proof-of-concept uses fabricated data.";

axis1 label=none value=(angle=90 color=gray55) offset=(3,3);
axis2 minor=none value=(color=cx7A378B) label=(color=gray55 'Deliveries (bar)') order=(0 to 1000 by 200);
axis3 minor=none value=(color=cxFF4500) label=(color=gray55 'Ontime (line)') order=(0 to 1 by .2);

pattern1 v=s c=cx7A378B;
symbol1 value=dot color=cxFF4500;

proc gbarline data=mydata anno=anno_img;
bar date / discrete type=sum sumvar=items
 width=7 space=3 coutline=gray55
 maxis=axis1 raxis=axis2
 autoref cref=grayaa clipref
 html=htmlvar
 des='' name="&name"; 
plot / type=sum sumvar=ontime
 raxis=axis3;
run;

quit;
ODS HTML CLOSE;
ODS LISTING;