%let name=tabasco_unblinged;
filename odsout '.';

/* 
SAS Imitation/Enhancement of 
http://www.tabascofoodservice.com/about_scoville.cfm
*/

/* This is totally fabricated (but plausibly-real) data, for a proof-of-concept */
data mydata;
format Max_Heat comma5.0;
input Sauce $ 1-20 Min_Heat Max_Heat;
datalines;
Habaņero             7000 8000
Pepper               2500 5000
Chipotle             1500 2500
Garlic Pepper        1200 1800
Green Pepper          600 1200
;
run;

data mydata; set mydata;
length myhtml $200;
myhtml=
 'title='||quote( 
  trim(left(sauce))||' Sauce'||'0d'x||
  'Heat Units: '||trim(left(Min_Heat))||' - '||trim(left(Max_Heat)))||
 ' href="http://countrystore.tabasco.com/index_category.cfm?tlcatid=2&catid=46"';
run;


goptions device=png;
 
ODS LISTING CLOSE;
ODS HTML path=odsout body="&name..htm" (title="Tabasco Chart (un-blinged)")
 style=htmlblue options(pagebreak='no');

goptions xpixels=180 ypixels=90;
goptions cback=yellow ctext=black border;
title1 h=8pt " ";
title2 h=16pt f="albany amt" link='tabasco_blinged.htm' "Click here to";
title3 h=16pt f="albany amt/bold" link='tabasco_blinged.htm' "Bling";
title4 h=16pt f="albany amt" link='tabasco_blinged.htm' "this graph!";
proc gslide des='' name="&name";
run;


goptions xpixels=700 ypixels=500;
goptions cback=white ctext=black;

goptions gunit=pct htitle=5 htext=3 ftitle="albany amt/bold" ftext="albany amt/bold";

axis1 label=('Heat Units') order=(0 to 8000 by 2000) minor=none;
axis2 label=none value=(angle=45) offset=(8,7);

pattern1 v=s c=cxEE3B3B;

title1 link="http://www.tabasco.com/main.cfm" 
 ls=1.5 height=.25in "Tabasco Sauce Comparison";

goptions noaltdesc;

proc gchart data=mydata;
vbar Sauce / type=sum sumvar=Max_Heat descending
  width=8 space=5
  raxis=axis1 maxis=axis2
  cframe=white noframe
  coutline=cx660000
  autoref cref=graydd clipref
/*
http://www.lettertech.com/images/2002HELMETS/2001%20FLAMES.jpg
*/
  html=myhtml
  des='' name="&name";
run;

quit;
ODS HTML CLOSE;
ODS LISTING;