%let name=bar2;
filename odsout '.';

data a;
input ITEM $ 1-6 CLASS $ 8-16 AMOUNT;
cards;
ITEM A 1st CLASS 11.8
ITEM B 1st CLASS 8.8 
ITEM C 1st CLASS 7.5
ITEM D 1st CLASS 3.2
ITEM A 2nd CLASS 10.5
ITEM B 2nd CLASS 9.3  
ITEM C 2nd CLASS 5.3
ITEM D 2nd CLASS 2.2
;
run;

data a; set a;
length htmlvar $500;
htmlvar='title='||quote(
 'Item: '|| trim(left(item)) ||'0D'x||
 'Class: '|| trim(left(class)) ||'0D'x||
 'Amount: '|| trim(left(amount))
)
||' '||
 'href="bar3.htm"';
run;



 GOPTIONS DEVICE=gif;
 
 ODS LISTING CLOSE;
 ODS HTML path=odsout body="&name..htm" (title="Grouped Bar Chart") style=minimal;
 goptions noborder;

goptions gunit=pct htitle=6 ftitle="albany amt/bold" htext=4.25 ftext="albany amt/bold";

axis1 label=none value=none;  /* only use the group axis for value/bar text */
axis2 label=('AMOUNT') order=(0 to 12 by 2) minor=(number=1) offset=(0,0);
axis3 label=none offset=(4,4);

legend1 label=none position=(bottom right inside) cframe=white mode=protect 
 shape=bar(3,3) cborder=black across=1;

/* pattern v=solid color=red; */
pattern1 v=solid color=cxbd0026;  /* reddish color */
pattern2 v=solid color=cx43a2ca;  /* this is the hex rgb color for mild blue */

title "Grouped Bar Chart";
proc gchart data=a; 
hbar class / discrete 
 type=sum sumvar=amount 
 group=item
 subgroup=class /* this controls the coloring */
 nostats
 maxis=axis1 /* midpoint axis */
 raxis=axis2 /* response/numeric axis */
 gaxis=axis3 /* group axis */
 space=0  /* space between bars in the same group */
 gspace=2 /* space between groups of bars */
 autoref /* reflines at every major axis tickmark */
 clipref /* put reflines behind the bars */
 cref=graycc
 legend=legend1
 coutline=black 
 html=htmlvar
 des="" name="&name" ;  
run;


 quit;
 ODS HTML CLOSE;
 ODS LISTING;