%let name=bar3;
filename odsout '.';

data a;
input ITEM $ 1-6 AMOUNT PREVIOUS;
cards;
ITEM A 11.8 10.8
ITEM B 10.5 8.8
ITEM C 8.4  7.8
ITEM D 5.8  6.4
ITEM E 4.4  5.0
ITEM F 2.3  1.6
;
run;

data a; set a;
length htmlvar $500;
htmlvar='title='||quote(
 'Item: '|| trim(left(item)) ||'0D'x||
 'Amount: '|| trim(left(amount))
)
||' '||
 'href="bar4.htm"';
run;


/* Annotate a symbol on the bars, showing previous year's value. */
data annomark;
set a;
length html $500;
html='title='||quote(
 'Item: '|| trim(left(item)) ||'0D'x||
 'Previous Year Amount: '|| trim(left(previous))
)
||' '||
 'href="bar4.htm"';
length function color  $8 text $30;
retain xsys ysys '2' when 'a';
function='label';
size=1.75;
color='cxbd0026';
position='5';
style='marker'; /* sas/graph 'marker' software font */
text='P';  /* 'P' is a diamond-shape in the marker font */
midpoint=item; x=previous; output;
run;


 GOPTIONS DEVICE=gif;
 
 ODS LISTING CLOSE;
 ODS HTML path=odsout body="&name..htm" (title="Bar-And-Symbol Chart") style=minimal;
 goptions noborder;

goptions gunit=pct htitle=6 ftitle="albany amt/bold" htext=4.25 ftext="albany amt/bold";

axis1 label=none offset=(8,8);
axis2 label=('AMOUNT') order=(0 to 12 by 2) minor=(number=1) offset=(0,0);

/* pattern v=solid color=red; */
pattern v=solid color=cx43a2ca;  /* this is the hex rgb color for mild blue */

title "Bar-And-Symbol Chart";
title2 "(bar=current year, symbol=previous year's value)";
proc gchart data=a anno=annomark; 
hbar item / discrete 
 type=sum sumvar=amount 
 nostats
 maxis=axis1 /* midpoint axis */
 raxis=axis2 /* response/numeric axis */
 autoref /* reflines at every major axis tickmark */
 clipref /* put reflines behind the bars */
 space=2 /* space between bars */
 cref=graycc
 coutline=black 
 html=htmlvar
 des="" name="&name" ;  
run;


 quit;
 ODS HTML CLOSE;
 ODS LISTING;