%let name=col1;
filename odsout '.';

data a;
input TIME AMOUNT;
cards;
1 9
2 13
3 22
4 24
5 28
6 32
7 37
8 41
9 42
10 49
11 45
;
run;

data a; set a;
length htmlvar $500;
htmlvar='title='||quote(
 'Time: '|| trim(left(Time)) ||'0D'x||
 'Amount: '|| trim(left(amount))
)
||' '||
 'href="col2.htm"';
run;


 GOPTIONS DEVICE=gif;
 
 ODS LISTING CLOSE;
 ODS HTML path=odsout body="&name..htm" (title="Simple Column Chart") style=minimal;
 goptions noborder;

goptions gunit=pct htitle=6 ftitle="albany amt/bold" htext=4.25 ftext="albany amt/bold";

axis1 label=('TIME');
axis2 label=(a=90 'AMOUNT') order=(0 to 50 by 10) minor=none offset=(0,0);

/* pattern v=solid color=red; */
pattern v=solid color=cx43a2ca;  /* this is the hex rgb color for mild blue */

title "Simple Column Chart";
proc gchart data=a; 
vbar time / discrete 
 type=sum sumvar=amount 
 maxis=axis1 /* midpoint axis */
 raxis=axis2 /* response/numeric axis */
 autoref /* reflines at every major axis tickmark */
 clipref /* put reflines behind the bars */
 cref=graycc
 coutline=black 
 width=5 /* make bars a little wider than the default */
 html=htmlvar
 des="" name="&name" ;  
run;


 quit;
 ODS HTML CLOSE;
 ODS LISTING;