%let name=col6;
filename odsout '.';

data a;
input TIME       CLASS $ 8-16 AMOUNT;
if class eq 'Bottom Pc' then amount=-1*amount;
cards;
1      Top Piece 7.5
1      Bottom Pc 5.0
2      Top Piece 6.0
2      Bottom Pc 2.0
3      Top Piece 9.5
3      Bottom Pc 0.8
4      Top Piece 7.0
4      Bottom Pc 5.0
5      Top Piece 9.0 
5      Bottom Pc 4.5
6      Top Piece 8.8
6      Bottom Pc 6.0
7      Top Piece 10.2
7      Bottom Pc 7.0
8      Top Piece 11.1
8      Bottom Pc 5.0
9      Top Piece 8.6
9      Bottom Pc 3.1
10     Top Piece 6.9 
10     Bottom Pc 1.7
11     Top Piece 9.4
11     Bottom Pc 4.4
12     Top Piece 7.0 
12     Bottom Pc 6.1
;
run;

data a; set a;
length htmlvar $500;
htmlvar='title='||quote(
 'Time: '|| trim(left(time)) ||'0D'x||
 'Piece: '|| trim(left(class)) ||'0D'x||
 'Amount: '|| trim(left(amount))
)
||' '||
 'href="col7.htm"';
run;


 GOPTIONS DEVICE=gif;
 
 ODS LISTING CLOSE;
 ODS HTML path=odsout body="&name..htm" (title="Floating-Column Column Chart") style=minimal;
 goptions noborder;

goptions gunit=pct htitle=6 ftitle="albany amt/bold" htext=4.25 ftext="albany amt/bold";

axis1 label=('TIME') offset=(5,5);  
axis2 label=(a=90 'AMOUNT') order=(-8 to 12 by 4) minor=(number=1) offset=(0,0);

pattern1 v=solid color=cx43a2ca;  /* reddish color */
pattern2 v=solid color=cx43a2ca;  /* this is the hex rgb color for mild blue */

title "Floating-Column Column Chart";
proc gchart data=a; 
vbar time / discrete 
 type=sum sumvar=amount 
 subgroup=class /* this controls the coloring */
 maxis=axis1 /* midpoint axis */
 raxis=axis2 /* response/numeric axis */
 autoref /* reflines at every major axis tickmark */
 clipref /* put reflines behind the bars */
 cref=graycc
 nolegend
 coutline=blue 
 width=5
 space=2
 html=htmlvar
 des="" name="&name" ;  
run;


 quit;
 ODS HTML CLOSE;
 ODS LISTING;