%let name=i_voted;

/* 
Set your current-working-directory (to read/write files), if you need to ...
%let rc=%sysfunc(dlgcdir('c:\someplace\public_html')); 
*/
filename odsout '.';

/*
Imitation of this sticker
https://www.sos.wa.gov/_assets/elections/I_Voted_Sticker_1.png
*/

%let blue=cx1872a4;
%let red=cxf06465;

data anno_sticker;
length function $8 color $12 style $35 text $100;
xsys='3'; ysys='3'; hsys='3'; when='a';
x=50; y=50; function='pie'; rotate=360; 
size=45; 
style='psolid'; color='white'; output;
style='pempty'; color='grayee'; output;
size=40;
style='psolid'; color="&blue"; angle=0; rotate=180; output;
style='psolid'; color="&red"; angle=0; rotate=-180; output;
x=13; y=40; function='move'; output;
x=100-13; y=60; function='bar'; style='solid'; line=0; color="white"; output;
function='label'; angle=.; rotate=.; style='franklin gothic demi cond'; size=22; position='>';
x=18.5; y=50; color="&blue"; text='I'; output;
x=29.5; y=50; color="&red"; text='VOTED'; output;
function='label'; style='wingdings'; position='+'; text='ab'x; color='white'; size=9.0;
do x = 30 to 70 by 10;
 y=75; output;
 y=25; output;
 end;

run;


goptions device=png;
goptions xpixels=500 ypixels=500;
goptions noborder;
goptions transparency;

ODS LISTING CLOSE;
ODS HTML path=odsout body="&name..htm"
 (title="I Voted Sticker") 
 style=htmlblue;

goptions gunit=pct htitle=4 htext=2.5 ftitle="albany amt" ftext="albany amt";
goptions ctext=gray33;

title;
footnote;
proc gslide anno=anno_sticker des='' name="&name";
run;

quit;
ODS HTML CLOSE;
ODS LISTING;