%let name=pie;
filename odsout '.';

libname mydata '../democd1';

/* MS, ND, DC, OH, OK, WY */
%let st=WY;  /* state abbreviation */

%let dataset=smm;

%let cmale=cx42C0FB;
%let cfemale=hotpink;


/* department store sales */
proc sql;
 create table plotdata as
 select unique year, fem_dept as Female, mal_dept as Male
 from mydata.&dataset
 where st="&st"
 order by year;
quit; run;

proc transpose data=plotdata out=plotdata;
by year;
run;

proc sql;
select fipnamel(stfips("&st")) into :fipnamel from plotdata;
quit; run;
%let fipnamel=%trim(&fipnamel);

proc datasets;
 modify plotdata;
 rename _name_ = sex;
 rename col1   = value;
run;




goptions xpixels=800 ypixels=600 hsize= vsize=;
goptions cback=white;
goptions border;

options dev=sasprtc printerpath=gif animduration=.5 animloop=1
 animoverlay=no animate=start center;

ods listing close;
ods html path=odsout body="&name..htm"
 (title="Clothing Sales (SAS/Graph gifanim)")
 style=htmlblue;


goptions gunit=pct htitle=6 htext=3 ftitle="albany amt/bold" ftext="albany amt";

options nobyline;
title1 ls=1.5 "Department Store Clothing Sales";
title2 h=5 f="albany amt/bold" "State = &fipnamel";

footnote1 h=5 font="albany amt/bold" "Year = #byval(year)";

pattern1 v=psolid c=&cfemale;
pattern2 v=psolid c=&cmale;

proc gchart data=plotdata;
by year;
pie sex / type=sum sumvar=value
 angle=90
 percent=inside
 slice=inside
 value=none
 noheading
 coutline=gray33
 des='' name="&name";
run;

quit;
ods html close;
ods listing;